#!/usr/bin/liquidsoap

# version du 10 juin 2020

set("log.file.path","/tmp/radiolive.log")

# Serveur settings
set("harbor.bind_addr","0.0.0.0")

# An emergency file
emergency = single("/home/radio/test/test.mp3")

# Les playlist
emoc = mksafe(normalize(playlist(mode='random', "/home/radio/emoc")))
ortie = mksafe(normalize(playlist(mode='random', "/home/radio/ortie")))
ortjer = mksafe(normalize(playlist(mode='random', "/home/radio/ort-jer")))
antoine = mksafe(normalize(playlist(mode='random', "/home/radio/antoine")))

# Playlist tournante
# le serveur est en temps UTC donc 10h serveur = 12h heure d'été FR...
playlist = switch(track_sensitive=true, [ # track_sensitive true par défaut, cad attend la fin de la piste!
  ({0h-8h}, emoc), 
  ({8h-10h}, ortjer), 
  ({10h-11h}, antoine), 
  ({11h-12h}, emoc), 
  ({12h-13h}, ortie), 
  ({13h-14h}, ortjer), 
  ({14h-15h}, emoc), 
  ({15h-18h}, ortjer), 
  ({18h-20h}, antoine), 
  ({20h-22h}, ortie),
  ({22h-24h}, emoc)
])

# live source
live = input.harbor("live",port=8080,password="****")

#live source bis
livebis = input.harbor("livebis",port=8081,password="****")

livemix = add([live,livebis])

# fallback
radio = fallback(track_sensitive=false,
                 [livemix,playlist,emergency])

output.icecast(%vorbis,
host = "localhost", port = 8000,
password = "****", mount = "radio",
url="http://5.196.66.118:8000/radio",
name="La Baleine Radio Test",
genre="Music",
description="La Baleine Radio Test",
public=true,
fallible=true,
radio)