Poussoir d'aiguilles pour machine à tricoter

/*
    Poussoir d'aiguilles (needle pusher) pour machine à tricoter Brother KH940
    Quimperia, La Baleine, 28 octobre 2019 / pierre<at>lesporteslogiques.net
    OpenSCAD version 2019.05 @ Kirin / debian stable, stretch 9.5 
    Dimensions prises d'après un exemplaire d'origine
*/
 
espacement = 8.9829;
 
module poussoir() {
    translate([0, 166, 0]) rotate([90, 0, 0]) linear_extrude(height=166) polygon(points=[ 
      [0,0],[30.5,0],[30.5,1.65],[25.5,3], 
      [21,3], [20,4.5], [12,4.5], [0, 1.85]] );
}
 
module dent(x) {
    translate([x, 0, 0]) linear_extrude(height=5) polygon(points=[ 
      [0,0], [8.983,0], [8.983,5], [6.883,5], [6.383, 5.5],
      [6.383, 13.1], [5.883, 13.6], [2.65, 13.6], [2.15, 13.1], 
      [2.15, 5.5], [1.6, 5], [0, 5]]);
}
 
module dents() {
    for (a =[0:19]) {
        dent(espacement * a);
    }
}  
 
difference() {
  poussoir();
  translate([-5, -6.533, 4.8]) rotate([0, 180, 270]) dents();
}
 
/* // volumes pleins, pour se faire une idée
poussoir();
translate([-5, -6.533, 4.8]) rotate([0, 180, 270]) dents();
*/